From 86f9edbc9d32dd6ad4637c6618499692f32c3b18 Mon Sep 17 00:00:00 2001
From: Oliver Kiddle <opk@zsh.org>
Date: Fri, 25 Aug 2017 15:08:30 +0200
Subject: 41598: new who and w completions

---
 Completion/Unix/Command/_w | 47 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 Completion/Unix/Command/_w

(limited to 'Completion/Unix/Command/_w')

diff --git a/Completion/Unix/Command/_w b/Completion/Unix/Command/_w
new file mode 100644
index 000000000..8fb4154c7
--- /dev/null
+++ b/Completion/Unix/Command/_w
@@ -0,0 +1,47 @@
+#compdef w
+
+local args
+
+case $OSTYPE in
+  linux*)
+    args=(
+      '(H -f --from)'{-f,--from}'[toggle display of remote hostname]'
+      '(H -h)--no-header[suppress the heading]'
+      '(H -i --ip-addr)'{-i,--ip-addr}'[display IP address instead of hostname]'
+      '(H -o --old-style -s --short)'{-o,--old-style}'[old style output format]'
+      '(H -s --short -o --old-style)'{-s,--short}'[use short output format]'
+      '(H -u --no-current)'{-u,--no-current}'[ignore the username while figuring out the current process and cpu times]'
+      + H
+      '(-)--help[display help information]'
+      '(-)'{-V,--version}'[display version information]'
+    )
+  ;;
+  *bsd*|darwin*|dragonfly*)
+    args+=( '-i[sort output by idle time]' )
+  ;|
+  openbsd*)
+    args+=( '-a[translate network addresses into names]' )
+  ;|
+  (free|net)bsd*|dragonfly*)
+    args+=( '-n[show network addresses as numbers]' )
+  ;|
+  *bsd*|dragonfly*)
+    args+=(
+      '-M+[extract values from specified core]:core file:_files'
+      '-N+[extract name list from specified system]:system file:_files'
+    )
+  ;|
+  freebsd*|dragonfly*)
+    args+=( '-d[dump process list on a per controlling tty basis]' )
+  ;|
+  solaris*)
+    args+=( '!(-s -w -l)'{-l,-w}
+      '-s[short output form]'
+      '(-)-u[produce only the heading line]'
+    )
+  ;|
+esac
+
+_arguments -S -s \
+  '(--no-header)-h[suppress the heading]' \
+  '*:user:_users' $args
-- 
cgit v1.2.3