Starting repo cleanup to make this not so awful

1 files changed, 129 insertions, 0 deletions

diff --git a/pinyadmin/sbin/newuser b/pinyadmin/sbin/newuser
new file mode 100755
index 0000000..e064f06
--- /dev/null
+++ b/pinyadmin/sbin/newuser
@@ -0,0 +1,129 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+
+use Email::Valid::Loose qw( );
+
+# If they passed any arguments, complain and exit.
+if ( scalar @ARGV ) {
+  print "You can't pass any arguments to this script!\n";
+  exit 2;
+};
+
+# If they didn't provide a terminal definition, then assume xterm.
+# Everybody emulates xterm to at least a basic extent.
+if ( not exists $ENV{"TERM"} ) {
+  $ENV{"TERM"} = "xterm";
+  print "I don't know what terminal you're using; guessing xterm...\n";
+};
+
+# Disable buffering.
+$|++;
+
+# Configure the strictness of our email checks.
+my $checker = Email::Valid::Loose->new
+  ( "-fqdn"        => 1
+  , "-fudge"       => 0
+  , "-local_rules" => 0
+  , "-mxcheck"     => 1
+  , "-tldcheck"    => 0
+  );
+
+my ( $email, $username, $password1, $password2 );
+
+while ( 1 ) {
+
+  print "Email address to associate with new user: ";
+  chomp ( $email = <STDIN> );
+
+  if ( $email eq "" ) {
+    print "You must provide an email address!\n";
+    next;
+  };
+
+  $email = $checker->address( $email );
+  if ( not defined $email ) {
+    print "Please, at least pretend to provide a valid email address.\n";
+    next;
+  };
+
+  last;
+
+};
+
+while ( 1 ) {
+
+  print "Desired username: ";
+  chomp ( $username = <STDIN> );
+
+  if ( $username eq "" ) {
+    print "You have to enter a username!\n";
+    next;
+  };
+  
+  if ( $username =~ /^git-|^ikiwiki-/ ) {
+    print "Your username cannot start with git- or ikiwiki-!\n";
+    next
+  };
+
+  if ( $username !~ /^[a-zA-Z0-9_.][a-zA-Z0-9_.-]+$/ ) {
+    print( "Usernames must consist only of letters, digits, underscores, periods, and dashes, and not start with a dash. Usernames are case sensitive.\n" );
+    next
+  };
+
+  last;
+
+};
+
+while ( 1 ) {
+
+  system( "stty", "-echo" );
+  print "Desired password: ";
+  chomp ( $password1 = <STDIN> );
+  print "\nRetype password: ";
+  chomp ( $password2 = <STDIN> );
+  print "\n";
+  system( "stty", "echo" );
+
+  if ( $password1 ne $password2 ) {
+    print "Provided passwords do not match; try again.\n";
+    next;
+  };
+
+  if ( $password1 eq "" ) {
+    print "You have to enter a password!\n";
+    next;
+  };
+
+  last;
+
+};
+
+my @saltchars =
+  ( 'a', 'b', 'c', 'd', 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l', 'm', 'n', 'o', 'p', 'q', 'r', 's', 't', 'u', 'v', 'w', 'x', 'y', 'z'
+  , 'A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', 'J', 'K', 'L', 'M', 'N', 'O', 'P', 'Q', 'R', 'S', 'T', 'U', 'V', 'W', 'X', 'Y', 'Z'
+  , '0', '1', '2', '3', '4', '5', '6', '7', '8', '9'
+  , '.', '/'
+  );
+
+my $salt = "\$6\$";
+
+foreach my $n ( 1 .. 16 ) {
+  $salt .= $saltchars[int ( rand ( scalar @saltchars ) )];
+};
+
+$salt .= "\$";
+
+my $crypt = crypt( $password1, $salt );
+
+my $ret = system( "/usr/sbin/useradd", "-c", "$email", "-k", "/var/empty", "-g", "users", "-m", "-p", $crypt, "-s", "/usr/bin/pinyshell", $username );
+
+if ( $ret ) {
+  print "An error occured creating the user; most likely, that username is already taken.\n";
+  exit 1;
+};
+
+print "Your user has been created. Try logging in!\n";
+
+exit 0;